股價距合理價值很遠然後開始暴量起漲

By | 2019-12-13

前兩天跟大家介紹我使用XS的方法,透過這樣的決策架構,我每天作功課的時間,就會聚焦在高勝率策略的開發,所以會漸漸的累積出一些勝率還不錯的交易策略,今天來跟大家介紹一個長期勝率蠻高(有七成),這兩年績效穩定的交易策略,這個策略是透過選股平台挑出股價距離合理價位很遠的股票,然後當這股票出現暴量起漲時進場。

這個策略的選股腳本如下

variable: idx(0), t(0);
input:r1(3, "假設未來十年營業利益年成長率");
input:r2(2, "未來十年平均年利率");
input:r3(100, "未來獲利折現合計淨值與市價比");

// 計算未來10年的營業利益折現值

value1=GetField("營業利益","Y"); //單位:百萬
value2=GetField("最新股本"); //單位:億
value3=GetField("每股淨值(元)","y");

value11 = maxlist(GetField("營業利益","Y"),GetField("營業利益","Y")[1],GetField("營業利益","Y")[2],GetField("營業利益","Y")[3],GetField("營業利益","Y")[4]);
value12 = minlist(GetField("營業利益","Y"),GetField("營業利益","Y")[1],GetField("營業利益","Y")[2],GetField("營業利益","Y")[3],GetField("營業利益","Y")[4]);

if trueall(value1>0,5) and (value11-value12)/value11<0.5 then begin
t = 0;
for idx =1 to 10 begin
t = t + value1 * power(1+r1/100,idx)/power(1+r2/100,idx);
end;

// t=百萬,value2=億,換成每股
value5 = t / value2 / 100;
value6=close/(value3+value5);

if value6<r3/100
then ret=1;
end;

outputfield(1, value5, 2, "估算每股營業利益");
outputfield(2, value6, 1, "市價/淨值比", order := -1);

這個選股腳本是先找出過去五年本業都獲利且五年裡的最高獲利與最低獲利的差異沒有很大,然後拿最新的營業利益當計算基礎 ,假設未來十年每年獲利都成長3%,然後用2%的利率當折現值,這樣計算出股票的合理價位,再跟市價去比,找出目前價值被低估的股票。

搭配的盤中洗價腳本如下

 Input: day(60,"日期區間");
Input: ratioLimit(14, "區間最大漲幅%");

Condition1 = H=highest(H,day);
//今日最高創區間最高價

Condition2 = V=highest(v,day);
//今日成交量創區間最大量

Condition3 = highest(H,day) < lowest(L,day)*(1 + ratioLimit*0.01);
//今日最高價距離區間最低價漲幅尚不大

if Condition1 And Condition2 And Condition3
then ret=1;

這個組合出來的策略在過去兩年的回測報告如下

這個策略的概念我用過很多次~ 價值被低估的股票開始絕地大反攻。差別只是評價方式的差別及對於絕地大反攻的價量定義。

這樣概念所寫出來的策略,我有不少勝率都不錯,所以把這樣的概念推荐給大家,祝大家找到績效比這個腳本更好的相關策略

回應