圖說技術指標的設計方式與背後的思維(三)

By | 2020-03-09

在討論過用開高低收成交量所衍生出來的各種技術指標之後,今天我們來討論趨勢型指標的思維與設計方式。

趨勢型技術指標在市場上被廣泛使用,像移動平均線,MACD等等大家耳熟能詳的技術指標都屬於趨勢指標。

趨勢指標最早被當成一個主流派別,應該是來自鼎鼎大名的道氏理論,道氏理論的核心是因為投資人趨吉避凶的心理,且具有心理學上的增強效應,市場會在沿著主要趨勢波動,我們可以透過股價的波動方向,來判斷市場的多空趨勢。

基於這樣的理論,技術分析者使用移動平均線等等的指標,來更清晰的觀察市場的主要趨勢。

最常被使用到的,是以下幾個指標

一,移動平均線

一般的移動平均線,就是把平均線期別裡的每個收盤價加總起來除以天期,XS裡的average函數就是這麼算的,腳本如下

SetBarMode(1);

input:thePrice(numericseries); //"價格序列"
input:Length(numericsimple); //"計算期間"

if Length > 0 then
Average = Summation(thePrice, Length) / Length
else 
Average =0;

因為是這麼計算出來的,所以很多分析師會用平均成本來介紹移動平均線,如果不同天期的移動平均線糾在在一起,我們會說短中長期的持股者的平均成本都差不多。

二,加權移動平均線

簡單的移動平均線最常被垢病的,是把過去的價格跟現在的價格視為一樣重要,這樣在價格波動時,可能反應不夠靈敏,所以有人主張,應該不能用簡單平均,要用加權平均來算移動平均線,給予最新的價格較高的權重。XS裡有一個函數Xaverage就是這樣的作法。

SetBarMode(2);

input:thePrice(numericseries); //"價格序列"
input:Length(Numeric); //"計算期間"

variable: Factor(0);

if length + 1 = 0 then Factor = 1 else Factor = 2 / (Length + 1);

if CurrentBar = 1 then
XAverage = thePrice
else
XAverage = XAverage[1] + Factor * (thePrice - XAverage[1]);

這樣的作法大家在自訂指標時可以拿來用,其中的Factor要怎麼訂,也是可以多方嚐試的。非常有名的MACD就是一個運用加權移動平均方法計算出來的指標。

三,MACD

我們先來看看這個指標的函數計算方式

SetBarMode(1);

// MACD function
// Input: Price序列, FastLength, SlowLength, MACDLength
// Output: DifValue, MACDValue, OscValue
// 
Input: Price(numericseries), FastLength(numericsimple), SlowLength(numericsimple), MACDLength(numericsimple);
Input: DifValue(numericref), MACDValue(numericref), OscValue(numericref);

DifValue = XAverage(price, FastLength) - XAverage(price, SlowLength);
MACDValue = XAverage(DifValue, MACDLength) ;
OscValue = DifValue - MACDValue;

從上面的腳本可以發現,MACD是把不同天期的加權移動平均線相減後再作一次加權移動平均。

以下圖為例,市場最常用的MACD參數是12,26,9

也就是計算12日的加權移動平均,26日的加權移動平均,然後前者減後者之後再計算九日的加權移動平均

四,TRIX三重指數平滑移動平均標

如果要說把加權移動平均的概念運用的最到位的,TRIX指標應該是其中一個,它的計算公式如下

Input: price(numericseries), length(numericsimple);

value1 = XAverage(price, length);
value2 = XAverage(value1, length);
value3 = XAverage(value2, length);
	
if CurrentBar = 1 then
	TRIX = 0
else
begin
    if value3[1] <> 0 then
        TRIX = (value3 - value3[1]) / value3[1]
    else
        TRIX = 0;
end;

可以看得出來,它是把股價,用同一期別,加權移動平均線計算了三次,所以會成為很平滑的線,以下圖為例,就是畫出9天跟15天的TRIX,線圖都非常的平滑,大方向也看的很清楚

今天跟大家介紹的是利用移動平均與加權移動平均的算法來掌握股價的大趨勢,運用這個方法來發展的自訂指標有非常的多,大家可以自己來試看看。

 

 

回應