依成交量分佈情況而設計的預估量演算法

By | 2019-07-19

由於預估量對當沖操作者很重要,一直有使用者來信詢問我們系統內建預估量的計算方法,也有不少熱心的使用者建議了一些演算方式。我們目前系統內建的演算法是依過往每分鐘成交量分佈比重,然後從當天的累計量去估算預估量,這樣的作法大家意見不大,但對於要拿多少天的歷史資料去估算成交量分佈情況,大家的意見差很多,我們公司的高手高高手,索性公開預估量的計算腳本,並且把成交量分佈比重究竟要拿多少天的歷史資料去估算,設成參數讓使用者自行來設計,這樣一來,大家就可以很容易的透過調整參數的方式,找到自己認為最貼近事實的估計量

這個估計量的腳本如果作成指標,其腳本如下

//
// 參數: 統計天期(N)
// 繪製: 當日估計成交量
//
// 支援任何頻率(分鐘/日)
//
// 計算方式: 依照過去N日, 每日1分鐘累計成交均量(統計天期平均), 算出每分鐘累計成交量的分佈比例, 
// 然後依照目前的累計日成交量以及分佈比例, 推算當日收盤估計成交量
//

input: length(5, "統計天數");

variable: BARPERDAY(270); // 1分鐘bar每一天270筆

array: arr_minvolume[](0); // (過去N日)每日每分鐘累計: 共length * 270筆
array: arr_minvolume_percent[270](0); // (平均)每分鐘累計成交量比例: 共270筆
array: arr_avg_minvolume[270](0); // (平均)每分鐘累計成交量: 共270筆

variable: _i(0), _j(0), _k(0);
variable: _totaldays(0);
variable: _lastdate(0);

Array_SetMaxIndex(arr_minvolume, length * 270);

{
print(text(
"currentbar=", numtostr(currentbar, 0), 
",date=", numtostr(date, 0), 
",time=", numtostr(time, 0),
",lastdate=", numtostr(_lastdate, 0),
",totaldays=", numtostr(_totaldays, 0)
));
}

if _lastdate = 0 then begin
// 跳過第一個不滿一天的資料
if barfreq = "Min" and time = 090000 then
_lastdate = date
else begin
// 日線的話則從20190101才開始算
if date >= 20190101 then
_lastdate = date;
end; 
end;

if _lastdate <> 0 and date <> _lastdate then begin
_lastdate = date;
_totaldays = _totaldays + 1;
if _totaldays >= length then begin
// 計算過去N天的成交量分佈
//
// 因為我可能跑在不同頻率上, 所以要先算出過去N日'1分鐘'資料的起點跟終點
//
variable: _start(0), _end(0), _startdate(0), _accvolume(0);

_end = 1;
while getfield("time", "1")[_end] <> 132900 begin
_end = _end + 1;
end;

_start = _end + BARPERDAY * length - 1;

// _start = 統計日期第一日第一筆1分鐘資料的位置
// _end = 統計日期最後一日最後一筆1分鐘資料的位置
//

// arr_minvolume[]: 儲存過去N天, 每一分鐘的日累積成交量
// arr_minvolume[1] = 09:00, 
// arr_minvolume[2] = 09:01
// arr_minvolume[271] = 第二天09:00
// ..
_startdate = getfield("date", "1")[_start];
_accvolume = 0;
for _i = _start downto _end begin
if _startdate <> getfield("date", "1")[_i] then begin
// 換日
_accvolume = 0;
_startdate = getfield("date", "1")[_i];
end;
_accvolume += getfield("volume", "1")[_i];
arr_minvolume[_start - _i + 1] = _accvolume; // 當日累積volume
end;

// arr_avg_minvolume[]: 每一分鐘的日平均累積成交量
//
for _j = 1 to BARPERDAY begin
arr_avg_minvolume[_j] = 0;
for _i = 1 to length begin
arr_avg_minvolume[_j] += arr_minvolume[_j + (_i - 1) * BARPERDAY];
end; 
end;
for _j = 1 to BARPERDAY begin
arr_avg_minvolume[_j] = arr_avg_minvolume[_j] / length;
end;

// arr_minvolume_percent[]: 每一分鐘的日平均累積成交量%
//
for _j = 1 to BARPERDAY begin
arr_minvolume_percent[_j] = arr_avg_minvolume[_j] / arr_avg_minvolume[BARPERDAY];
end;

{
print(text(
"main-date=", numtostr(date, 0), ",",
"main-time=", numtostr(time, 0), ",",
"start=", numtostr(_start, 0), ",",
"end=", numtostr(_end, 0), ",",
"startdate=", numtostr(getfield("date", "1")[_start], 0), ",", numtostr(getfield("time", "1")[_start], 0), ",",
"enddate=", numtostr(getfield("date", "1")[_end], 0), ",", numtostr(getfield("time", "1")[_end], 0), ","
));

for _i = 1 to 270 begin
print(text(
numtostr(_i, 0), "=", 
numtostr(arr_minvolume_percent[_i] * 100, 2))); 
end; 
}
end;
end;

if _totaldays >= length then begin
// 如果已經有分佈資料了, 則計算估計成交量
//
variable: _estvolume(0);
variable: _timeindex(0);
variable: _time(0), _v(0);

// 算出目前時間應該是1~270的哪一筆
// 分鐘線的話就用bar的時間
// 日線的話, 如果是歷史日線, 就用收盤時間估算, 如果是最後一天(盤中日線), 用目前時間估算
//
if barfreq = "Min" then
_time = time
else begin
if date < currentdate then
_time = 132900
else 
_time = currenttime;
end;
_timeindex = floor(timediff(_time, 090000, "M")) + 1;
_timeindex = minlist(_timeindex, 270);
_timeindex = maxlist(1, _timeindex);

// 預估量 = 累計到目前的日成交量 / 這個時間點之前所佔的日成交量%
//
_v = GetField("volume", "D");
if arr_minvolume_percent[_timeindex] > 0 then
_estvolume = _v / arr_minvolume_percent[_timeindex]
else
_estvolume = 0;

plot1(_estvolume, "預估量");
end;





我也試著把這個預估量的腳本寫成函數

input: length(numericsimple);

variable: BARPERDAY(270); // 1分鐘bar每一天270筆

array: arr_minvolume[](0); // (過去N日)每日每分鐘累計: 共length * 270筆
array: arr_minvolume_percent[270](0); // (平均)每分鐘累計成交量比例: 共270筆
array: arr_avg_minvolume[270](0); // (平均)每分鐘累計成交量: 共270筆

variable: _i(0), _j(0), _k(0);
variable: _totaldays(0);
variable: _lastdate(0);

Array_SetMaxIndex(arr_minvolume, length * 270);

{
print(text(
"currentbar=", numtostr(currentbar, 0), 
",date=", numtostr(date, 0), 
",time=", numtostr(time, 0),
",lastdate=", numtostr(_lastdate, 0),
",totaldays=", numtostr(_totaldays, 0)
));
}

if _lastdate = 0 then begin
// 跳過第一個不滿一天的資料
if barfreq = "Min" and time = 090000 then
_lastdate = date
else begin
// 日線的話則從20190101才開始算
if date >= 20190101 then
_lastdate = date;
end; 
end;

if _lastdate <> 0 and date <> _lastdate then begin
_lastdate = date;
_totaldays = _totaldays + 1;
if _totaldays >= length then begin
// 計算過去N天的成交量分佈
//
// 因為我可能跑在不同頻率上, 所以要先算出過去N日'1分鐘'資料的起點跟終點
//
variable: _start(0), _end(0), _startdate(0), _accvolume(0);

_end = 1;
while getfield("time", "1")[_end] <> 132900 begin
_end = _end + 1;
end;

_start = _end + BARPERDAY * length - 1;

// _start = 統計日期第一日第一筆1分鐘資料的位置
// _end = 統計日期最後一日最後一筆1分鐘資料的位置
//

// arr_minvolume[]: 儲存過去N天, 每一分鐘的日累積成交量
// arr_minvolume[1] = 09:00, 
// arr_minvolume[2] = 09:01
// arr_minvolume[271] = 第二天09:00
// ..
_startdate = getfield("date", "1")[_start];
_accvolume = 0;
for _i = _start downto _end begin
if _startdate <> getfield("date", "1")[_i] then begin
// 換日
_accvolume = 0;
_startdate = getfield("date", "1")[_i];
end;
_accvolume += getfield("volume", "1")[_i];
arr_minvolume[_start - _i + 1] = _accvolume; // 當日累積volume
end;

// arr_avg_minvolume[]: 每一分鐘的日平均累積成交量
//
for _j = 1 to BARPERDAY begin
arr_avg_minvolume[_j] = 0;
for _i = 1 to length begin
arr_avg_minvolume[_j] += arr_minvolume[_j + (_i - 1) * BARPERDAY];
end; 
end;
for _j = 1 to BARPERDAY begin
arr_avg_minvolume[_j] = arr_avg_minvolume[_j] / length;
end;

// arr_minvolume_percent[]: 每一分鐘的日平均累積成交量%
//
for _j = 1 to BARPERDAY begin
arr_minvolume_percent[_j] = arr_avg_minvolume[_j] / arr_avg_minvolume[BARPERDAY];
end;

{
print(text(
"main-date=", numtostr(date, 0), ",",
"main-time=", numtostr(time, 0), ",",
"start=", numtostr(_start, 0), ",",
"end=", numtostr(_end, 0), ",",
"startdate=", numtostr(getfield("date", "1")[_start], 0), ",", numtostr(getfield("time", "1")[_start], 0), ",",
"enddate=", numtostr(getfield("date", "1")[_end], 0), ",", numtostr(getfield("time", "1")[_end], 0), ","
));

for _i = 1 to 270 begin
print(text(
numtostr(_i, 0), "=", 
numtostr(arr_minvolume_percent[_i] * 100, 2))); 
end; 
}
end;
end;

if _totaldays >= length then begin
// 如果已經有分佈資料了, 則計算估計成交量
//
variable: _estvolume(0);
variable: _timeindex(0);
variable: _time(0), _v(0);

// 算出目前時間應該是1~270的哪一筆
// 分鐘線的話就用bar的時間
// 日線的話, 如果是歷史日線, 就用收盤時間估算, 如果是最後一天(盤中日線), 用目前時間估算
//
if barfreq = "Min" then
_time = time
else begin
if date < currentdate then
_time = 132900
else 
_time = currenttime;
end;
_timeindex = floor(timediff(_time, 090000, "M")) + 1;
_timeindex = minlist(_timeindex, 270);
_timeindex = maxlist(1, _timeindex);

// 預估量 = 累計到目前的日成交量 / 這個時間點之前所佔的日成交量%
//
_v = GetField("volume", "D");
if arr_minvolume_percent[_timeindex] > 0 then
_estvolume = _v / arr_minvolume_percent[_timeindex]
else
_estvolume = 0;
destvolume=_estvolume;
end;










 

利用這個Destvolume的函數,我們就可以寫出預估量比五日均量增加N%的警示腳本

 

input:day(10,"預估量估算期間");
input:period(20,"均量計算期間");
input:ratio(80," 暴量比例");
if destvolume(day) crosses over average(volume,period)*(1+ratio/100)
and close>close[1]*1.01
then ret=1;

 

 

至於預估量的成交量分配要用過往幾天的值來估算,我個人偏向於不要太長,因為太長要計算的時間很久,而且跟目前的交易實況可能會有落差。

以上是預估量的計算腳本大公開

有不同想法的朋友也可以再提出來

大家的目標都是想要把預估量計算的愈來愈貼近實際量

 

 

 

回應