為自己的觀察名單標上交易訊號

By | 2015-10-01

我有一份觀察名單,在這個名單裡的股票,是我想要"找點買"的股票,這些股票有些是朋友報我的,有些是我自己研究後的心得,但什麼時候才是對的買點?這是一門大學問,特別是開盤時間裡不一定有空看盤,而且人生苦短,每天下班累的半死還要一直作功課,都讓我一直想辦法看看電腦能不能幫我更多的忙,最好是每天電腦自動幫我列出所有我觀察名單中的股票,有那些出現買進訊號?有那些還要觀望?有那些超跌了要開始留意? 我手上的持股,那些過熱了要開始留意賣點? 那些該賣出了? 這樣一來我每天只要回家花個五分鐘看一遍,就可以留單了。

以下是我做的小小實驗,透過XS選股,每天做出一份我觀察名單的交易訊號清單。

步驟一是先訂好交易訊號的依據。

例如我想用多空分數這個指標來做交易訊號的依據

我的規則是

1.當多空分數從5以下突破5代表"買進"訊號

2.當多空分數突破5之後,一直在五日均線之上,代表"持有"訊號

3.當多空分數突破10,代表" 過熱"

4.當多空分數跌破10,代表"賣出"

5.當多空分數跌破10之後且一直在五日均線之下,代表"觀望"

6.當多空分數跌破5,代表"超賣"

就像下面這張圖

100102

 

如果我們拿台積電當例子,大家可以從下面這張圖看出多空分數與台積電股價的對應關係
100101

 

大家如果對於多空分數很陌生,我把腳本再貼一次

// 利用多種指標, 計算多空分數
//
variable: count(0);

// 每次計算都要reset
count = 0;

//------------------ Arron指標 -------------------//
variable: arron_up(0),arron_down(0),arron_oscillator(0);//arron oscillator
arron_up=(25-nthhighestbar(1,high,25))/25*100;
arron_down=(25-nthlowestbar(1,low,25))/25*100;
arron_oscillator=arron_up-arron_down;
if arron_up > arron_down and arron_up > 70 and arron_oscillator > 50
then count=count+1;

//------------------ 隨機漫步指標 ---------------//
variable: RWIH(0),RWIL(0);
value1 = standarddev(close,10,1);
value2 = average(truerange,10);
if value1 <> 0 and value2 <> 0 then
begin
RWIH=(high-low[9])/value2*value1;
RWIL=(high[9]-low)/value2*value1;
end;

if RWIH > RWIL
then count=count+1;

//------------------ 順勢指標 -------------------//
variable:bp1(0),abp1(0);
if truerange <> 0 then
bp1=(close-close[1])/truerange*100;//順勢指標

abp1=average(bp1,10);
if abp1 > 0
then count=count+1;

//---------- CMO錢德動量擺動指標 ----------------//
variable:SU(0),SD(0),CMO1(0), SUSUM(0), SDSUM(0);

if close >= close[1] then
SU=CLOSE-CLOSE[1]+SU[1]
else
SU=SU[1];

if close < close[1] then
SD=CLOSE[1]-CLOSE+SD[1]
else
SD=SD[1];

SUSUM = summation(SU,9);
SDSUM = summation(sd,9);
if (SUSUM+SDSUM) <> 0 then
cmo1=(SUSUM-SDSUM)/(SUSUM+SDSUM)*100;

if linearregslope(cmo1,5) > 0
then count=count+1;

//------------------ RSI指標 -------------------//
variable: rsiShort(0), rsiLong(0);
rsiShort=rsi(close,5);
rsiLong=rsi(close,10);
if rsiShort > rsiLong and rsiShort < 90
then count=count+1;

//----------------- MACD指標 -------------------//
variable: Dif_val(0), MACD_val(0), Osc_val(0);
MACD(Close, 12, 26, 9, Dif_val, MACD_val, Osc_val);
if osc_val > 0
then count=count+1;

//----------------- MTM指標 -------------------//
if mtm(10) > 0
then count=count+1;

//----------------- KD指標 --------------------//
variable:rsv1(0),k1(0),d1(0);
stochastic(9,3,3,rsv1,k1,d1);
if k1 > d1 and k1 < 80
then count=count+1;

//----------------- DMI指標 -------------------//
variable:pdi_value(0),ndi_value(0),adx_value(0);
DirectionMovement(14,pdi_value,ndi_value,adx_value);
if pdi_value > ndi_value
then count=count+1;

//----------------- AR指標 -------------------//
variable: arValue(0);
arValue = ar(26);
if linearregslope(arValue,5) > 0
then count=count+1;

//----------------- ACC指標 -----------------//
if acc(10) > 0
then count=count+1;

//----------------- TRIX指標 ----------------//
if trix(close,9) > trix(close,15)
then count=count+1;

//----------------- SAR指標 ----------------//
if close > SAR(0.02, 0.02, 0.2)
then count=count+1;

//----------------- 均線指標 ----------------//
if average(close,5) > average(close,12)
then count=count+1;

// Return value
//
TechScore = count;

它其實代表的是在14個具代表性指標中有多少個指標目前是處於多頭狀態中。

 

 

定義好交易訊號之後,我們就可以根據這個標準來寫選股的腳本

這邊我們得先跟大家報告一下這種根據不同情況給不同交易訊號的腳本,在撰寫時,基本架構如下圖

100103

以下是一個撰寫這種依不同狀況,多輸出結果的腳本樣本
100104

如果要看完整的說明,請參考以下的連結

http://xshelp.xq.com.tw/xslesson/if..then

根據上述的語法結構,我就寫了多空分數的交易訊號腳本如下:

setoutputname1("多空分數交易訊號");
value1 = techscore();
value2 = average(value1, 10);

Value3 = CountIF(value2 crosses above 5,5);

value4=CountIF(value2 crosses below 10,5);

if value3 >1 then
begin
ret = 1 ;
outputfield1("買進");
end
else
if value2 >5 and value2 >average(value2,5)
then begin
ret=1 ;
outputfield1("持有");
end
else
if value2 >=10
then begin
ret=1 ;
outputfield1("過熱");
end
else
if value4>1
then begin
ret=1;
outputfield1("賣出");
end
else
if value2 >5 and value2 <average(value2,5) then begin
ret=1;
outputfield1("觀望");
end
else
if value2<=5
then begin
ret=1;
outputfield1("超賣");
end;

接下來我就用這個腳本來跑我的觀察名單,其結果如下圖

100105

我把這個選股策略啟動每日自動報行之後,就可以每天看到根據多空分數所跑出來的交易訊號了。

接下來是把除了多空分數之外,其他的交易訊號規則也寫在腳本中,xs的腳本透過兩個語法
來定義選股結果欄位的名稱及欄位呈現的內容

setoutputname1(“多空分數交易訊號"); 代表的是欄位的名稱
outputfield1(“超賣"); 代表的是這個欄位的輸出結果

所以如果有第二個交易訊號的定義時,我們就可以用setoutputname2及outputfield2來呈現,

例如我們可以寫出

setoutputname2("RSI交易訊號");
IF RSI cross over 20
then begin
ret=1;
outputfield2("買進");

end;

這樣我們就可以在選股結果頁出現第二個交易訊號欄位。

透過這樣的方式,我們就可以每天看到我們觀察名單中的股票,根據特定標準,那些該進場,那些該出場了。

這樣一來,是不是可以節省不少時間呢?

 

 

 

你可能會有興趣的文章

回應